develooper Front page | perl.perl5.porters | Postings from July 2001

[PATCH] lib/h2xs.t (was Re: [PATCH] h2xs)

Thread Previous | Thread Next
From:
Nicholas Clark
Date:
July 7, 2001 13:00
Subject:
[PATCH] lib/h2xs.t (was Re: [PATCH] h2xs)
Message ID:
20010707210017.H59620@plum.flirble.org
On Sat, Jul 07, 2001 at 05:26:39PM +0100, Nicholas Clark wrote:
> On Sat, Jul 07, 2001 at 11:19:17AM -0500, Jarkko Hietaniemi wrote:
> > On Fri, Jul 06, 2001 at 11:25:14PM +0100, Nicholas Clark wrote:
> > > Some fool made a change to ExtUtils::Constant that stopped h2xs working. :-(
> > > [Hmm. Without regression tests for h2xs and friends, how are we going to
> > 
> > lib/h2xs.t doesn't work for you?
> 
> I don't think that made a special case for me. Bleadperl 11148 goes
> 
> $ ./perl -I lib utils/h2xs png.h 
> Writing ext/Png/Png.pm
> Writing ext/Png/Png.xs
> ExtUtils::Constant doesn't know how to handle values of type HASH(0x250af0) used in macro HANDLE_CHUNK_AS_DEFAULT at lib/ExtUtils/Constant.pm line 709.
> ExtUtils::Constant doesn't know how to handle values of type HASH(0x250b38) used in macro HANDLE_CHUNK_IF_SAFE at lib/ExtUtils/Constant.pm line 709.
> ExtUtils::Constant doesn't know how to handle values of type HASH(0x250b68) used in macro HANDLE_CHUNK_NEVER at lib/ExtUtils/Constant.pm line 709.
> 
> and I wasn't even aware of h2xs.t, hence no patch to it to stop
> this bug repeating.

OK. This will correctly barf with h2xs broken as before, but passes with
a fixed h2xs. I've somewhat re-written it with a loop instead of a
cut&paste which hopefully will make it easy to add more tests.

Does h2xs want a -q option to be quiet?

Do we want to split ExtUtils.t into 4?
[test build a .pm only module
 test build a simple .xs module
 test build the current constant tester
 test build something from h2xs
]
Nicholas Clark

--- lib/h2xs.t.orig	Sat Jun 23 19:15:49 2001
+++ lib/h2xs.t	Sat Jul  7 20:49:15 2001
@@ -1,4 +1,4 @@
-#!./perl
+#!./perl -w
 
 # Some quick tests to see if h2xs actually runs and creates files as 
 # expected.  File contents include date stamps and/or usernames
@@ -13,6 +13,8 @@
 
 # use strict; # we are not really testing this
 use File::Path;  # for cleaning up with rmtree()
+use Test;
+
 
 my $extracted_program = '../utils/h2xs'; # unix, nt, ...
 if ($^O eq 'VMS') { $extracted_program = '[-.utils]h2xs.com'; }
@@ -35,21 +37,10 @@
 # $name should differ from system header file names and must
 # not already be found in the t/ subdirectory for perl.
 my $name = 'h2xst';
+my $header = "$name.h";
 
-print "1..17\n";
-
-my @result = ();
-my $result = '';
-my $expectation = '';
-
-# h2xs warns about what it is writing hence the (possibly unportable)
-# 2>&1 dupe:
-# does it run?
-@result = `$^X $lib $extracted_program -f -n $name $dupe`;
-print(((!$?) ? "" : "not "), "ok 1\n");
-$result = join("",@result);
-
-$expectation = <<"EOXSFILES";
+my @tests = (
+"-f -n $name", <<"EOXSFILES",
 Writing $name/$name.pm
 Writing $name/$name.xs
 Writing $name/Makefile.PL
@@ -59,41 +50,7 @@
 Writing $name/MANIFEST
 EOXSFILES
 
-# accomodate MPW # comment character prependage
-if ($^O eq 'MacOS') {
-    $result =~ s/#\s*//gs;
-}
-
-#print "# expectation is >$expectation<\n";
-#print "# result is >$result<\n";
-# Was the output the list of files that were expected?
-print((($result eq $expectation) ? "" : "not "), "ok 2\n");
-# Were the files created?
-my $t = 3;
-$expectation =~ s/Writing //; # remove leader
-foreach (split(/Writing /,$expectation)) {
-    chomp;  # remove \n
-    if ($^O eq 'MacOS') {
-        $_ = ':' . join(':',split(/\//,$_));
-        $_ =~ s/$name:t:1.t/$name:t\/1.t/; # is this an h2xs bug?
-    }
-    print(((-e $_) ? "" : "not "), "ok $t\n");
-    $t++;
-}
-
-# clean up
-rmtree($name);
-
-# does it run with -X and omit the h2xst.xs file?
-@result = ();
-$result = '';
-# The extra \" around -X are for VMS but do no harm on NT or Unix
-@result = `$^X $lib $extracted_program \"-X\" -f -n $name $dupe`;
-print(((!$?) ? "" : "not "), "ok $t\n");
-$t++;
-$result = join("",@result);
-
-$expectation = <<"EONOXSFILES";
+"\"-X\" -f -n $name", <<"EONOXSFILES",
 Writing $name/$name.pm
 Writing $name/Makefile.PL
 Writing $name/README
@@ -102,22 +59,64 @@
 Writing $name/MANIFEST
 EONOXSFILES
 
-if ($^O eq 'MacOS') { $result =~ s/#\s*//gs; }
-#print $expectation;
-#print $result;
-print((($result eq $expectation) ? "" : "not "), "ok $t\n");
-$t++;
-$expectation =~ s/Writing //; # remove leader
-foreach (split(/Writing /,$expectation)) {
+"-f -n $name $header", <<"EOXSFILES",
+Writing $name/$name.pm
+Writing $name/$name.xs
+Writing $name/Makefile.PL
+Writing $name/README
+Writing $name/t/1.t
+Writing $name/Changes
+Writing $name/MANIFEST
+EOXSFILES
+);
+
+my $total_tests = 3; # opening, closing and deleting the header file.
+for (my $i = $#tests; $i > 0; $i-=2) {
+  # 1 test for running it, 1 test for the expected result, and 1 for each file
+  # use the () to force list context and hence count the number of matches.
+  $total_tests += 2 + (() = $tests[$i] =~ /(Writing)/sg);
+}
+
+plan tests => $total_tests;
+
+ok (open (HEADER, ">$header"));
+print HEADER <<HEADER or die $!;
+#define Camel 2
+#define Dromedary 1
+HEADER
+ok (close (HEADER));
+
+while (my ($args, $expectation) = splice @tests, 0, 2) {
+  # h2xs warns about what it is writing hence the (possibly unportable)
+  # 2>&1 dupe:
+  # does it run?
+  my $prog = "$^X $lib $extracted_program $args $dupe";
+  @result = `$prog`;
+  ok ($?, 0, "running $prog");
+  $result = join("",@result);
+
+  # accomodate MPW # comment character prependage
+  if ($^O eq 'MacOS') {
+    $result =~ s/#\s*//gs;
+  }
+
+  #print "# expectation is >$expectation<\n";
+  #print "# result is >$result<\n";
+  # Was the output the list of files that were expected?
+  ok ($result, $expectation, "running $prog");
+
+  $expectation =~ s/Writing //; # remove leader
+  foreach (split(/Writing /,$expectation)) {
     chomp;  # remove \n
     if ($^O eq 'MacOS') {
-        $_ = ':' . join(':',split(/\//,$_));
-        $_ =~ s/$name:t:1.t/$name:t\/1.t/; # is this an h2xs bug?
+      $_ = ':' . join(':',split(/\//,$_));
+      $_ =~ s/$name:t:1.t/$name:t\/1.t/; # is this an h2xs bug?
     }
-    print(((-e $_) ? "" : "not "), "ok $t\n");
-    $t++;
-}
+    ok (-e $_, 1, "$_ missing");
+  }
 
-# clean up
-rmtree($name);
+  # clean up
+  rmtree($name);
+}
 
+ok (unlink ($header), 1, $!);

Thread Previous | Thread Next


nntp.perl.org: Perl Programming lists via nntp and http.
Comments to Ask Bjørn Hansen at ask@perl.org | Group listing | About