develooper Front page | perl.perl5.porters | Postings from February 2000

Re: Patch for fields.pm (Was: Re: On Pseudohashes)

Thread Previous | Thread Next
From:
Gurusamy Sarathy
Date:
February 27, 2000 14:05
Subject:
Re: Patch for fields.pm (Was: Re: On Pseudohashes)
Message ID:
200002272208.OAA28387@maul.activestate.com
On Fri, 14 Jan 2000 18:43:30 PST, Peter Scott wrote:
>Nervous as I am about bringing up pseudo-hashes at this point, I wish to 
>offer the following patch for 5.005_63, which puts a convenience function 
>in fields.pm that creates a pseudo-hash for those who don't want to type 
>the natural numbers and make sure the pairs match up.
>
>The interface came out of a discussion with Damian Conway where I evinced 
>this desire, we kicked around ideas like qp//, and he eventually suggested 
>this interface and said y'all could blame him for it :-)  (But not for the 
>idea itself or its implementation.)  The only change I made to the 
>interface was to shorten the name since it cannot be exported as Damian 
>recommended or it would be treated as a field.  Perhaps because of that it 
>ought to live in another module, but I can't see where.

I've renamed fields::ph() to fields::phash() (for the ostensible reason
that the latter is a better name ;-) and also added a fields::new()
method.

This should make it unnecessary for people to set %FIELDS directly
or even have to know about it.


Sarathy
gsar@ActiveState.com
-----------------------------------8<-----------------------------------
Change 5293 by gsar@auger on 2000/02/27 21:57:40

	support fields::new() and fields::phash() to create pseudo-hash
	objects and plain pseudo-hashes respectively (this avoids users
	from having to diddle %FIELDS directly); update documentation to
	suit (from original fields::phash() implementation by Peter
	Scott <Peter@PSDT.com>)

Affected files ...

... //depot/perl/lib/fields.pm#13 edit
... //depot/perl/pod/perldelta.pod#164 edit
... //depot/perl/pod/perlfunc.pod#155 edit
... //depot/perl/pod/perlref.pod#18 edit
... //depot/perl/t/lib/fields.t#9 edit

Differences ...

==== //depot/perl/lib/fields.pm#13 (text) ====
Index: perl/lib/fields.pm
--- perl/lib/fields.pm.~1~	Sun Feb 27 14:00:11 2000
+++ perl/lib/fields.pm	Sun Feb 27 14:00:11 2000
@@ -8,59 +8,117 @@
 
     {
         package Foo;
-        use fields qw(foo bar _private);
+        use fields qw(foo bar _Foo_private);
+	sub new {
+	    my Foo $self = shift;
+	    unless (ref $self) {
+		$self = fields::new($self);
+		$self->{_Foo_private} = "this is Foo's secret";
+	    }
+	    $self->{foo} = 10;
+	    $self->{bar} = 20;
+	    return $self;
+	}
     }
-    ...
-    my Foo $var = new Foo;
+
+    my Foo $var = Foo::->new;
     $var->{foo} = 42;
 
-    # This will generate a compile-time error.
+    # this will generate a compile-time error
     $var->{zap} = 42;
 
+    # subclassing
     {
         package Bar;
         use base 'Foo';
-        use fields 'bar';             # hides Foo->{bar}
-        use fields qw(baz _private);  # not shared with Foo
+        use fields qw(baz _Bar_private);	# not shared with Foo
+	sub new {
+	    my $class = shift;
+	    my $self = fields::new($class);
+	    $self->SUPER::new();		# init base fields
+	    $self->{baz} = 10;			# init own fields
+	    $self->{_Bar_private} = "this is Bar's secret";
+	    return $self;
+	}
     }
 
 =head1 DESCRIPTION
 
-The C<fields> pragma enables compile-time verified class fields.  It
-does so by updating the %FIELDS hash in the calling package.
+The C<fields> pragma enables compile-time verified class fields.
+
+NOTE: The current implementation keeps the declared fields in the %FIELDS
+hash of the calling package, but this may change in future versions.
+Do B<not> update the %FIELDS hash directly, because it must be created
+at compile-time for it to be fully useful, as is done by this pragma.
 
 If a typed lexical variable holding a reference is used to access a
-hash element and the %FIELDS hash of the given type exists, then the
-operation is turned into an array access at compile time.  The %FIELDS
-hash maps from hash element names to the array indices.  If the hash
-element is not present in the %FIELDS hash, then a compile-time error
-is signaled.
+hash element and a package with the same name as the type has declared
+class fields using this pragma, then the operation is turned into an
+array access at compile time.
+
+The related C<base> pragma will combine fields from base classes and any
+fields declared using the C<fields> pragma.  This enables fields
+inheritance to work properly.
 
-Since the %FIELDS hash is used at compile-time, it must be set up at
-compile-time too.  This is made easier with the help of the 'fields'
-and the 'base' pragma modules.  The 'base' pragma will copy fields
-from base classes and the 'fields' pragma adds new fields.  Field
-names that start with an underscore character are made private to a
-class and are not visible to subclasses.  Inherited fields can be
+Field names that start with an underscore character are made private to
+the class and are not visible to subclasses.  Inherited fields can be
 overridden but will generate a warning if used together with the C<-w>
 switch.
 
 The effect of all this is that you can have objects with named fields
 which are as compact and as fast arrays to access.  This only works
 as long as the objects are accessed through properly typed variables.
-For untyped access to work you have to make sure that a reference to
-the proper %FIELDS hash is assigned to the 0'th element of the array
-object (so that the objects can be treated like an pseudo-hash).  A
-constructor like this does the job:
+If the objects are not typed, access is only checked at run time.
+
+The following functions are supported:
+
+=over 8
+
+=item new
+
+fields::new() creates and blesses a pseudo-hash comprised of the fields
+declared using the C<fields> pragma into the specified class.
+This makes it possible to write a constructor like this:
+
+    package Critter::Sounds;
+    use fields qw(cat dog bird);
+
+    sub new {
+	my Critter::Sounds $self = shift;
+	$self = fields::new($class) unless ref $self;
+	$self->{cat} = 'meow';				# scalar element
+	@$self->{'dog','bird'} = ('bark','tweet');	# slice
+	return $self;
+    }
+
+=item phash
+
+fields::phash() can be used to create and initialize a plain (unblessed)
+pseudo-hash.  This function should always be used instead of creating
+pseudo-hashes directly.
+
+If the first argument is a reference to an array, the pseudo-hash will
+be created with keys from that array.  If a second argument is supplied,
+it must also be a reference to an array whose elements will be used as
+the values.  If the second array contains less elements than the first,
+the trailing elements of the pseudo-hash will not be initialized.
+This makes it particularly useful for creating a pseudo-hash from
+subroutine arguments:
+
+    sub dogtag {
+	my $tag = fields::phash([qw(name rank ser_num)], [@_]);
+    }
+
+fields::phash() also accepts a list of key-value pairs that will
+be used to construct the pseudo hash.  Examples:
+
+    my $tag = fields::phash(name => "Joe",
+			    rank => "captain",
+			    ser_num => 42);
 
-  sub new
-  {
-      my $class = shift;
-      no strict 'refs';
-      my $self = bless [\%{"$class\::FIELDS"}], $class;
-      $self;
-  }
+    my $pseudohash = fields::phash(%args);
 
+=back
 
 =head1 SEE ALSO
 
@@ -92,6 +150,8 @@
     my $class = shift;
     return unless @_;
     my $package = caller(0);
+    # avoid possible typo warnings
+    %{"$package\::FIELDS"} = () unless %{"$package\::FIELDS"};
     my $fields = \%{"$package\::FIELDS"};
     my $fattr = ($attr{$package} ||= [1]);
     my $next = @$fattr;
@@ -131,11 +191,13 @@
     }
 }
 
-sub inherit  # called by base.pm when $base_fields is nonempty
-{
+sub inherit  { # called by base.pm when $base_fields is nonempty
     my($derived, $base) = @_;
     my $base_attr = $attr{$base};
     my $derived_attr = $attr{$derived} ||= [];
+    # avoid possible typo warnings
+    %{"$base\::FIELDS"} = () unless %{"$base\::FIELDS"};
+    %{"$derived\::FIELDS"} = () unless %{"$derived\::FIELDS"};
     my $base_fields    = \%{"$base\::FIELDS"};
     my $derived_fields = \%{"$derived\::FIELDS"};
 
@@ -157,27 +219,66 @@
 
 sub _dump  # sometimes useful for debugging
 {
-   for my $pkg (sort keys %attr) {
-      print "\n$pkg";
-      if (@{"$pkg\::ISA"}) {
-         print " (", join(", ", @{"$pkg\::ISA"}), ")";
-      }
-      print "\n";
-      my $fields = \%{"$pkg\::FIELDS"};
-      for my $f (sort {$fields->{$a} <=> $fields->{$b}} keys %$fields) {
-         my $no = $fields->{$f};
-         print "   $no: $f";
-         my $fattr = $attr{$pkg}[$no];
-         if (defined $fattr) {
-            my @a;
-	    push(@a, "public")    if $fattr & _PUBLIC;
-            push(@a, "private")   if $fattr & _PRIVATE;
-            push(@a, "inherited") if $no < $attr{$pkg}[0];
-            print "\t(", join(", ", @a), ")";
-         }
-         print "\n";
-      }
-   }
+    for my $pkg (sort keys %attr) {
+	print "\n$pkg";
+	if (@{"$pkg\::ISA"}) {
+	    print " (", join(", ", @{"$pkg\::ISA"}), ")";
+	}
+	print "\n";
+	my $fields = \%{"$pkg\::FIELDS"};
+	for my $f (sort {$fields->{$a} <=> $fields->{$b}} keys %$fields) {
+	    my $no = $fields->{$f};
+	    print "   $no: $f";
+	    my $fattr = $attr{$pkg}[$no];
+	    if (defined $fattr) {
+		my @a;
+		push(@a, "public")    if $fattr & _PUBLIC;
+		push(@a, "private")   if $fattr & _PRIVATE;
+		push(@a, "inherited") if $no < $attr{$pkg}[0];
+		print "\t(", join(", ", @a), ")";
+	    }
+	    print "\n";
+	}
+    }
+}
+
+sub new {
+    my $class = shift;
+    $class = ref $class if ref $class;
+    return bless [\%{$class . "::FIELDS"}], $class;
+}
+
+sub phash {
+    my $h;
+    my $v;
+    if (@_) {
+	if (ref $_[0] eq 'ARRAY') {
+	    my $a = shift;
+	    @$h{@$a} = 1 .. @$a;
+	    if (@_) {
+		$v = shift;
+		unless (! @_ and ref $v eq 'ARRAY') {
+		    require Carp;
+		    Carp::croak ("Expected at most two array refs\n");
+		}
+	    }
+	}
+	else {
+	    if (@_ % 2) {
+		require Carp;
+		Carp::croak ("Odd number of elements initializing pseudo-hash\n");
+	    }
+	    my $i = 0;
+	    @$h{grep ++$i % 2, @_} = 1 .. @_ / 2;
+	    $i = 0;
+	    $v = [grep $i++ % 2, @_];
+	}
+    }
+    else {
+	$h = {};
+	$v = [];
+    }
+    [ $h, @$v ];
 }
 
 1;

==== //depot/perl/pod/perldelta.pod#164 (text) ====
Index: perl/pod/perldelta.pod
--- perl/pod/perldelta.pod.~1~	Sun Feb 27 14:00:11 2000
+++ perl/pod/perldelta.pod	Sun Feb 27 14:00:11 2000
@@ -1042,6 +1042,12 @@
 or slice it deletes the values corresponding to the keys (but not the keys
 themselves).  See L<perlref/"Pseudo-hashes: Using an array as a hash">.
 
+Pseudo-hash slices with constant keys are now optimized to array lookups
+at compile-time.
+
+The C<fields> pragma now provides ways to create pseudo-hashes, via
+fields::new() and fields::phash().  See L<fields>.
+
 =head2 C<goto &sub> and AUTOLOAD
 
 The C<goto &sub> construct works correctly when C<&sub> happens

==== //depot/perl/pod/perlfunc.pod#155 (text) ====
Index: perl/pod/perlfunc.pod
--- perl/pod/perlfunc.pod.~1~	Sun Feb 27 14:00:11 2000
+++ perl/pod/perlfunc.pod	Sun Feb 27 14:00:11 2000
@@ -1477,8 +1477,8 @@
 second--glance appear to be an lvalue context may be fixed in a future
 release.
 
-See L<perlref/"Pseudo-hashes"> for specifics on how exists() acts when
-used on a pseudo-hash.
+See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
+on how exists() acts when used on a pseudo-hash.
 
 Use of a subroutine call, rather than a subroutine name, as an argument
 to exists() is an error.

==== //depot/perl/pod/perlref.pod#18 (text) ====
Index: perl/pod/perlref.pod
--- perl/pod/perlref.pod.~1~	Sun Feb 27 14:00:11 2000
+++ perl/pod/perlref.pod	Sun Feb 27 14:00:11 2000
@@ -546,51 +546,58 @@
 element of the array has to be a hash reference that maps field names
 to array indices.  Here is an example:
 
-   $struct = [{foo => 1, bar => 2}, "FOO", "BAR"];
+    $struct = [{foo => 1, bar => 2}, "FOO", "BAR"];
 
-   $struct->{foo};  # same as $struct->[1], i.e. "FOO"
-   $struct->{bar};  # same as $struct->[2], i.e. "BAR"
+    $struct->{foo};  # same as $struct->[1], i.e. "FOO"
+    $struct->{bar};  # same as $struct->[2], i.e. "BAR"
 
-   keys %$struct;   # will return ("foo", "bar") in some order
-   values %$struct; # will return ("FOO", "BAR") in same some order
+    keys %$struct;   # will return ("foo", "bar") in some order
+    values %$struct; # will return ("FOO", "BAR") in same some order
 
-   while (my($k,$v) = each %$struct) {
+    while (my($k,$v) = each %$struct) {
        print "$k => $v\n";
-   }
+    }
 
 Perl will raise an exception if you try to access nonexistent fields.
-For better performance, Perl can also
-do the translation from field names to array indices at compile time for
-typed object references.  See L<fields>.
+To avoid inconsistencies, always use the fields::phash() function
+provided by the C<fields> pragma.
+
+    use fields;
+    $pseudohash = fields::phash(foo => "FOO", bar => "BAR");
+
+For better performance, Perl can also do the translation from field
+names to array indices at compile time for typed object references.
+See L<fields>.
 
 There are two ways to check for the existence of a key in a
 pseudo-hash.  The first is to use exists().  This checks to see if the
 given field has ever been set.  It acts this way to match the behavior
 of a regular hash.  For instance:
 
-	$phash = [{foo =>1, bar => 2, pants => 3}, 'FOO'];
-	$phash->{pants} = undef;
+    use fields;
+    $phash = fields::phash([qw(foo bar pants)], ['FOO']);
+    $phash->{pants} = undef;
 
-	print exists $phash->{foo};    # true, 'foo' was set in the declaration
-	print exists $phash->{bar};    # false, 'bar' has not been used.
-	print exists $phash->{pants};  # true, your 'pants' have been touched
+    print exists $phash->{foo};    # true, 'foo' was set in the declaration
+    print exists $phash->{bar};    # false, 'bar' has not been used.
+    print exists $phash->{pants};  # true, your 'pants' have been touched
 
 The second is to use exists() on the hash reference sitting in the
 first array element.  This checks to see if the given key is a valid
 field in the pseudo-hash.
 
-	print exists $phash->[0]{bar};	# true, 'bar' is a valid field
-	print exists $phash->[0]{shoes};# false, 'shoes' can't be used
+    print exists $phash->[0]{bar};	# true, 'bar' is a valid field
+    print exists $phash->[0]{shoes};# false, 'shoes' can't be used
 
 delete() on a pseudo-hash element only deletes the value corresponding
 to the key, not the key itself.  To delete the key, you'll have to
 explicitly delete it from the first hash element.
 
-	print delete $phash->{foo};     # prints $phash->[1], "FOO"
-	print exists $phash->{foo};     # false
-	print exists $phash->[0]{foo};  # true, key still exists
-	print delete $phash->[0]{foo};  # now key is gone
-	print $phash->{foo};            # runtime exception
+    print delete $phash->{foo};     # prints $phash->[1], "FOO"
+    print exists $phash->{foo};     # false
+    print exists $phash->[0]{foo};  # true, key still exists
+    print delete $phash->[0]{foo};  # now key is gone
+    print $phash->{foo};            # runtime exception
 
 =head2 Function Templates
 

==== //depot/perl/t/lib/fields.t#9 (xtext) ====
Index: perl/t/lib/fields.t
--- perl/t/lib/fields.t.~1~	Sun Feb 27 14:00:11 2000
+++ perl/t/lib/fields.t	Sun Feb 27 14:00:11 2000
@@ -66,8 +66,7 @@
 
 package main;
 
-sub fstr
-{
+sub fstr {
    my $h = shift;
    my @tmp;
    for my $k (sort {$h->{$a} <=> $h->{$b}} keys %$h) {
@@ -90,7 +89,7 @@
     'Foo::Bar::Baz' => 'b1:1,b2:2,b3:3,foo:4,bar:5,baz:6',
 );
 
-print "1..", int(keys %expect)+7, "\n";
+print "1..", int(keys %expect)+13, "\n";
 my $testno = 0;
 while (my($class, $exp) = each %expect) {
    no strict 'refs';
@@ -125,9 +124,25 @@
 print "not " unless "@$obj1{'b1','_b1','b1'}" eq "28 44 28";
 print "ok ", ++$testno, "\n";
 
+my $ph = fields::phash(a => 1, b => 2, c => 3);
+print "not " unless fstr($ph) eq 'a:1,b:2,c:3';
+print "ok ", ++$testno, "\n";
+
+$ph = fields::phash([qw/a b c/], [1, 2, 3]);
+print "not " unless fstr($ph) eq 'a:1,b:2,c:3';
+print "ok ", ++$testno, "\n";
+
+$ph = fields::phash([qw/a b c/], [1]);
+print "not " if exists $ph->{b} or exists $ph->{c} or !exists $ph->{a};
+print "ok ", ++$testno, "\n";
+
+eval '$ph = fields::phash("odd")';
+print "not " unless $@ && $@ =~ /^Odd number of/;
+print "ok ", ++$testno, "\n";
+
 #fields::_dump();
 
-# check if 
+# check if fields autovivify
 {
     package Foo;
     use fields qw(foo bar);
@@ -140,3 +155,17 @@
     print $a->{foo}[1], "\n";
     print $a->{bar}->{A}, "\n";
 }
+
+# check if fields autovivify
+{
+    package Bar;
+    use fields qw(foo bar);
+    sub new { return fields::new($_[0]) }
+
+    package main;
+    my Bar $a = Bar::->new();
+    $a->{foo} = ['a', 'ok ' . ++$testno, 'c'];
+    $a->{bar} = { A => 'ok ' . ++$testno };
+    print $a->{foo}[1], "\n";
+    print $a->{bar}->{A}, "\n";
+}
End of Patch.

Thread Previous | Thread Next


nntp.perl.org: Perl Programming lists via nntp and http.
Comments to Ask Bjørn Hansen at ask@perl.org | Group listing | About